こんにちは、くのへ@MasazaneKunoheです。

在宅ワーク時には「本日の業務予定」を上司に送ることがルールになっている方はいませんか？
一発で定型メールを作っちゃいましょう。

本日の業務予定報告メール一発作成

↓コピペで動くと思います

Sub 今日の業務予定報告メール作成()

'objAppoItemsに予定アイテム一式をセット
  Dim objMAPI As Object
  Set objMAPI = GetNamespace("MAPI")
 
  Dim objAppoItems As Object
  Set objAppoItems = objMAPI.GetDefaultFolder(olFolderCalendar).Items

'objAppoItemsを開始時間(Start)でソートする。
'「繰り返し予定」も対象とする。
  objAppoItems.Sort "[Start]"
  objAppoItems.IncludeRecurrences = True
 
'予定アイテム一式から今日の予定を抽出し、strTodayScheduleに書き込む。
  Dim objAppo As Object
  Dim strTodaySchedule As String
 
  For Each objAppo In objAppoItems
    If Format(objAppo.Start, "short date") = Format(Now, "Short Date") Then
      
      strTodaySchedule = strTodaySchedule & Format(objAppo.Start, "hh:nn") & "　: " & objAppo.Subject & vbCrLf
      
    End If
  Next objAppo

'メールを作成する
  Dim objMailItem As Object
  Set objMailItem = CreateItem(olMailItem)

  Dim strSignature As String

  With objMailItem
    .Display
    strSignature = .Body
    
    .To = "testAddress@xx.xx"       '正宛先
    .CC = "CCtestAddress@xx.xx"     'CC宛先
    .Subject = "【連絡】本日の業務を開始します"               '件名

    
  '本文
    .Body = "■■さん" & vbCrLf & vbCrLf & _
            "おはようございます。" & vbCrLf & _
            "本日の業務を開始します。" & vbCrLf & vbCrLf & _
            "＜本日の予定＞" & vbCrLf & _
            "① ■■■" & vbCrLf & _
            "② ■■■" & vbCrLf & _
            "③ ■■■" & vbCrLf & vbCrLf & _
            "＜本日の会議＞" & vbCrLf & _
            strTodaySchedule & vbCrLf & _
            strSignature
    
    .Display    '作成メールを表示する。下書き保存や送信BOXに送る場合は↓こちら

  End With
End Sub

使ってみるとこうなります

このコードは前半部分が本日のスケジュールを抽出する部分、後半がメール作成です。
これを実行すると、こんな感じで本日の会議予定までパッと一瞬で出来るので、超便利に使えます。

これはただの「今日の予定を抽出するマクロ」と「メール作成マクロ」の組み合わせだね～

このコード、私はほぼ毎日使ってます。超便利。
ではまた別の記事で～
🦅バサバサ～

くのへスタジオはこちら。
Outlook-VBAコーナーはこちら。